Plant API (Suggestion)

paulevs · May 15th 2021

Hi to everyone, some time ago I asked a question about the API for plants. As API of such kind is not implemented yet I listed a small suggestions about plant API that can be possibly added to allow creating custom plants with plugins or modify existing plants (probably) here.

This is a list of how plant can be defined:

Plants have a unique ID by type (with key set plugin-plant-name -> integer number) if Rising World on Unity uses plant IDs like Java version. This tale will aloow safely add and remove plugins with plants;
Any plant can be defined as a list of mesh objects (probably in OBJ format);
Each plant have a vertex color information how wind should be applied to it (for example – red color gradient);
Each plant has an instance of shader with texture mask (single texture with 3 channels) for sub-surface scattering (leaves, red channel), glowing parts (for plants that can glow, green channel) and refracted parts (blue channel);
Plant can defile its LOD (for example LOD1 and LOD2) to improve game performance, the most distant LOD is a simple geometry with plant image and it can be generated by the game itself;
Plants can have a specific events like cutting event to make possible change default plant behavior to something unique or add additional functionality (like collecting rubber from Hevea or collecting fruits);
Plants can be one of 3 suggested types:

Tree Plant (Cuttable Plant)

Can be cutted with axes or other tools (probably the tool can be defined in plant to allow users create custom tools to cut plants);
Will drop its content after cutting and leave a stump;
Stump can be uprooted and can define its drop;
Models are stored in a list of 3 separate lists (or in multi-indexed array) – random variants of upper parts, stumps and full for each plant age, all 3 lists have the same length and parts have the same indecies to make cutting operation smooth (without model changing);
Drops will be scattered across upper plant model part.

Bush Plant (Collectable plant)

A small plant that will be collected;
Models are stored in a list of lists (or in multi-indexed array) – random variants for each age.

Grass Plant (Ambient Plant)

A small plant that will be added to grass material depending on biome;
Is a 2D texture with defined size;
Couldn’t be collected.

How plant shader can be organized:

All plants can use the same shader with complex behavior;
Texture mask for sub-surface scattering (leaves, red channel), glowing parts (for plants that can glow, green channel) and refracted parts (blue channel). This will alow make plants of almost any kind – from bioluminescent mushrooms (which are technically not plants but can be defined in this way) to any kind of tree.

Sub-surface scattering

This is a common shader technique for thin plant parts like leaves as they will scatter light. There are many different approaches on it

Sub-surface Scattering Example (Unity)

Wind mask

Color/Colors baked inside model vertices, colors can indicate different reaction on wind

Example Of Wind Mask

I hope you enjoy the idea of such API, discussion and criticism are welcome

paulevs · May 16th 2021

This is a simple demonstration of plant shader made by me in Unity. All plants models were made hastily in Blender and exported as .dae into Unity (to save vertex colors used as wind movement markers). Trees used sub-surface scattering and wind mask (the same for grass), mushrooms - glowing mask, the shader is the same for all plants

Video

Shader itself (Only code)

Code

Shader "Custom/PlantShader" {
    Properties {
        _MainTex ("Texture (RGBA)", 2D) = "white" {}
        _MaskTex ("Mask (RGB)", 2D) = "black" {}
        _NormalMap ("Normal Map (RGB)", 2D) = "black" {}
        _Cutoff("Alpha Cutoff", Range(0.0, 0.9)) = 0.5
    }
    SubShader {
        Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
        LOD 200
        Cull Off 
        
        CGPROGRAM
        #pragma surface surf Plant alphatest:_Cutoff addshadow vertex:vert
        #pragma target 3.0
        
        sampler2D _MainTex, _MaskTex, _NormalMap;
        
        struct Input {
            float2 uv_MainTex;
        };
        
        // Custom surface structure
        struct SurfaceOutputCustom {
            fixed3 Albedo;
            fixed3 Normal;
            fixed3 Emission;
            fixed3 Mask;
            half Specular;
            fixed Gloss;
            fixed Alpha;
        };
        
        // Leaves and plant waving
        void vert (inout appdata_full v) {
            float intensity = v.color.r * 0.3;
            float dx = sin(_Time.x * 100.0 + v.vertex.z + v.vertex.y * 2) * intensity;
            float dz = sin(_Time.x * 73.3 + v.vertex.x + v.vertex.y * 2) * intensity;
            v.vertex.x += dx;
            v.vertex.z += dz;
        }
        
        // Texture & Mask input, normals
        void surf(Input IN, inout SurfaceOutputCustom o) {
            fixed4 color = tex2D(_MainTex, IN.uv_MainTex);
            fixed4 mask = tex2D(_MaskTex, IN.uv_MainTex);
            fixed4 normal = tex2D(_NormalMap, IN.uv_MainTex);
            o.Albedo = color.rgb;
            o.Alpha = color.a;
            o.Mask = mask.rgb;
            o.Normal = UnpackNormal(normal);
            o.Emission = mask.g * color.rgb;
        }
        
        // Light calculations - surface, luminocity, sub-surface scattering
        half4 LightingPlant(SurfaceOutputCustom s, half3 lightDir, half atten) {
            fixed3 mask = s.Mask;
            half NdotL = dot(s.Normal, lightDir);
            half light = max(_LightColor0.rgb * (NdotL * atten), _LightColor0.rgb * mask.r * atten);
            //light = max(light, mask.g);
            
            half4 color;
            color.rgb = s.Albedo * light;
            color.a = s.Alpha;
            return color;
        }
        
        ENDCG
    }
}

Display More

Unity Project Sources

Assembled exe (can be used as screensaver)

paulevs · May 16th 2021

As it is impossible to see how mushrooms are glowing - here is a small screenshot of the same scene with only one point light and without ambient lights

Screenshot

paulevs · May 16th 2021

Updated shader variant - now it uses more colors to detect large plant movements (branches on trees) and have smooth movement for small plants and leaves

Shader video

Updated shader code

Code

Shader "Custom/PlantShader" {
    Properties {
        _MainTex ("Texture (RGBA)", 2D) = "white" {}
        _MaskTex ("Mask (RGB)", 2D) = "black" {}
        _NormalMap ("Normal Map (RGB)", 2D) = "black" {}
        _Cutoff("Alpha Cutoff", Range(0.0, 0.9)) = 0.5
    }
    SubShader {
        Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
        LOD 200
        Cull Off 
        
        CGPROGRAM
        #pragma surface surf Plant alphatest:_Cutoff addshadow vertex:vert
        #pragma target 3.0
        
        sampler2D _MainTex, _MaskTex, _NormalMap;
        
        struct Input {
            float2 uv_MainTex;
        };
        
        // Custom surface structure
        struct SurfaceOutputCustom {
            fixed3 Albedo;
            fixed3 Normal;
            fixed3 Emission;
            fixed3 Mask;
            half Specular;
            fixed Gloss;
            fixed Alpha;
        };
        
        // Leaves and plant waving
        void vert (inout appdata_full v) {
            float intensity = v.color.g * 2.0;
            float3 worldPos = mul(unity_ObjectToWorld, float4(v.vertex.xyz, 1)).xyz;
            float offset = _Time.x * 13.0 + worldPos.z * 0.1 + worldPos.y * 0.15;
            float big_dx = sin(offset) * intensity;
            float big_dy = cos(offset) * intensity;
            
            intensity = v.color.r * 0.2;
            offset = worldPos.z * 0.5 + worldPos.x * 0.5 + worldPos.y;
            float dx = sin(_Time.x * 100.0 + offset) * intensity;
            float dz = sin(_Time.x * 75.0 + offset) * intensity;
            float dy = sin(_Time.x * 50.0 + offset) * intensity;
            
            v.vertex.x += dx + big_dx;
            v.vertex.z += dz * 0.2;
            v.vertex.y += dy + big_dy;
        }
        
        // Texture & Mask input, normals
        void surf(Input IN, inout SurfaceOutputCustom o) {
            fixed4 color = tex2D(_MainTex, IN.uv_MainTex);
            fixed4 mask = tex2D(_MaskTex, IN.uv_MainTex);
            fixed4 normal = tex2D(_NormalMap, IN.uv_MainTex);
            o.Albedo = color.rgb;
            o.Alpha = color.a;
            o.Mask = mask.rgb;
            o.Normal = UnpackNormal(normal);
            o.Emission = mask.g * color.rgb;
        }
        
        // Light calculations - surface, luminocity, sub-surface scattering
        half4 LightingPlant(SurfaceOutputCustom s, half3 lightDir, half atten) {
            fixed3 mask = s.Mask;
            half NdotL = dot(s.Normal, lightDir);
            half light = max(_LightColor0.rgb * (NdotL * atten), _LightColor0.rgb * mask.r * atten);
            //light = max(light, mask.g);
            
            half4 color;
            color.rgb = s.Albedo * light;
            color.a = s.Alpha;
            return color;
        }
        
        ENDCG
    }
}

Display More

How vertex color masks on model looks like

Red color marks leaves movement, green color - branch movement (it was mapped as distance to zero)

Script to colorize mesh by distance (for Blender, Pytnon)

The latest compiled version

yahwho · May 28th 2021

Hehe looks like someone's eaten one of those mushrooms in that shader video

Plant API (Suggestion)

Participate now!

Similar Threads

QoL Electricity / Fuel etc.

Status Update: Vegetation und Gras

Survey results